package Pisg::Parser::Format::clog;

# Documentation for the Pisg::Parser::Format modules is found in Template.pm

use strict;
$^W = 1;

sub new
{
    my ($type, %args) = @_;
    my $self = {
        cfg => $args{cfg},

        normalline => '^(\d+):\d+:\d+ <([^>]+)> (.*)',
        actionline => '^(\d+):\d+:\d+ \* (\S+) (.*)',
        thirdline  => '^(\d+):(\d+):\d+ --- (\S+) (\S+) (\S+) (.*)',
    };

    bless($self, $type);
    return $self;
}

sub normalline
{
    my ($self, $line, $lines) = @_;
    my %hash;

    if ($line =~ /$self->{normalline}/o) {

        $hash{hour}   = $1;
        $hash{nick}   = remove_prefix($2);
        $hash{saying} = $3;

        return \%hash;
    } else {
        return;
    }
}

sub actionline
{
    my ($self, $line, $lines) = @_;
    my %hash;

    if ($line =~ /$self->{actionline}/o) {

        $hash{hour}   = $1;
        $hash{nick}   = remove_prefix($2);
        $hash{saying} = $3;

        return \%hash;
    } else {
        return;
    }
}

sub thirdline
{
    my ($self, $line, $lines) = @_;
    my %hash;

    if ($line =~ /$self->{thirdline}/o) {

        $hash{hour} = $1;
        $hash{min}  = $2;

        if (($3) eq 'kick:') {
            if ($line =~ /^\S+ --- kick: (\S+) was kicked by (\S+) (.*)$/) {
                $hash{kicker} = $2;
                $hash{nick} = $1;
            }

        } elsif (($3) eq 'mode:') {
            if ($line =~ /^\S+ --- mode: (\S+) set (\S+) (.*)$/) {
                $hash{newmode} = $2;
                $hash{nick} = $1;
            }

        } elsif (($3) eq 'join:') {
            $hash{newjoin} = $4;
            $hash{nick} = $4;

        } elsif (($3) eq 'nick:') {
            $hash{newnick} = $6;
            $hash{nick} = $4;

        } elsif (($3) eq 'topic:') {
            if ($line =~ /^\S+ --- topic: set to '(.*?)' by (\S+)$/) {
                $hash{newtopic} = $1;
                $hash{nick} = $2;
            }

	}
        return \%hash;

    } else {
        return;
    }
}

sub remove_prefix
{
    my $str = shift;

    $str =~ s/^@//;
    $str =~ s/^\+//;

    return $str;

}

1;
